.gitlab-ci.yml

-image: "debian"
-
 build:
     stage: build
+    image: debian
     before_script:
         - echo "deb http://deb.debian.org/debian stretch-backports main" >> /etc/apt/sources.list
         - apt update -qq
@@ -11,3 +10,9 @@ build:
     script:
         - ./bootstrap.sh
         - ninja -C build/
+
+nix:
+    stage: build
+    image: nixos/nix:latest
+    script:
+        - nix-build

default.nix

+{ pkgs ? import <nixpkgs> {},
+}:
+with pkgs;
+let
+  firmware = callPackage ./nix/firmware.nix {};
+  openocd = callPackage ./nix/openocd.nix { };
+in
+{
+  openocd = stdenv.mkDerivation {
+    name = "openocd-card10";
+    src = ./openocd;
+    phases = [ "unpackPhase" "installPhase" ];
+    buildInputs = [ openocd makeWrapper ];
+    installPhase = ''
+      mkdir -p $out/bin $out/share
+      cp -ar . $out/share/openocd
+      makeWrapper ${openocd}/bin/openocd $out/bin/openocd-card10 \
+        --add-flags "-f $out/share/openocd/scripts/interface/cmsis-dap.cfg" \
+        --add-flags "-f $out/share/openocd/scripts/target/max32665.cfg"
+    '';
+  };
+  inherit firmware;
+}

nix/firmware.nix

+{ fetchFromGitHub, pkgsCross, python3, ninja, meson, gcc }:
+
+let
+  micropython = fetchFromGitHub {
+    owner = "micropython";
+    repo = "micropython";
+    rev = "62f004ba424920a01e60c7a9a064b8ec9cd69c12";
+    sha256 = "0bhbdw4zlk4yr798x8k9pk3q85xnbqj1f2362l65wv1815ajzx5l";
+    fetchSubmodules = true;
+  };
+in
+  pkgsCross.armhf-embedded.stdenv.mkDerivation {
+    name = "card10";
+    src = ./..;
+    postPatch = ''
+      substituteInPlace card10-cross.ini \
+        --replace arm-none-eabi arm-none-eabihf
+      rmdir lib/micropython/micropython
+      ln -s ${micropython}/ lib/micropython/micropython
+    '';
+    nativeBuildInputs = [ ninja meson python3 gcc ];
+    mesonFlags = [
+      "--cross-file card10-cross.ini"
+      "--optimization s"
+    ];
+    ninjaFlags = [ "-v" ];
+  }

nix/openocd.nix

+{ openocd, fetchFromGitHub, autoreconfHook, git, which }:
+openocd.overrideAttrs (oa: {
+  src = fetchFromGitHub {
+    owner = "maximmbed";
+    repo = "openocd";
+    rev = "e71ac88c9dbfa4ee1405d7a86376119dcc887ed1";
+    sha256 = "18yc1wyclmjxqg6jilfcm60hi01pgqc4dilsmksqbhg23m6x4ycw";
+    fetchSubmodules = true;
+  };
+  nativeBuildInputs = oa.nativeBuildInputs ++ [
+    autoreconfHook
+    git
+    which
+  ];
+  enableParallelBuilding = true;
+})

shell.nix

+with import <nixpkgs> {};
+pkgsCross.armhf-embedded.stdenv.mkDerivation {
+  name = "env";
+  buildInputs = [ ninja meson python3 gcc bashInteractive ];
+}